Fórmula avanzada: funciones de fecha

La Fórmula Avanzada de Jotform Tablas proporciona funciones que te permiten recuperar, formatear y realizar operaciones con fecha y hora en Jotform Tablas.

Notas:

• Jotform Tablas convierte las fechas en números de serie secuenciales para ser utilizados en cálculos. Por defecto, 1900-01-01 es 1, y 2025-01-21 es 45678 porque son 45,678 días desde el 1 de enero de 1900.
• Los parámetros de función etiquetados como datetime aceptan únicamente valores de tipo de columna Selector de Fecha o Fecha y Hora.
• Algunos parámetros de función aceptan cadenas de fecha en varios formatos (es decir, YYYY-MM-DD, M/D/YYYY, MM/DD/YYYY).

Aquí tienes la lista de funciones de fecha y hora que puedes usar en Jotform Tablas:

Ver también:

• Operadores
• Funciones de Texto
• Funciones Lógicas
• Funciones Numéricas
• Funciones de Array y Registro

DATEADD

Añade un número específico de unidades a una fecha particular.

Sintaxis:

DATEADD(date,number,unit)

Las unidades aceptadas son

• years
• months
• weeks
• days
• hours
• minutes
• seconds

Ejemplos:

• =DATEADD("06/20/2025",3,"days") devolverá 23 jun, 2025.
• =DATEADD("6/20/2025",-1,"year") devolverá 20 jun, 2024.
• =DATEADD({Date Picker},1,"week") añadirá 1 semana al valor de la columna Date Picker.
• =DATEADD(TODAY(),-48,"hours") restará 48 horas a la fecha actual.
• =DATEADD(TEXT("June 20, 2025","MM/DD/YYYY"),3,"days") devolverá 23 jun, 2025.

DATESTR

Convierte datetime al formato YYYY-MM-DD. El parámetro datetime acepta únicamente valores de tipo de columna Selector de Fecha o Fecha y Hora. Para otros tipos de valores y formatos de retorno, consulta TEXT.

Sintaxis:

DATESTR(datetime)

Ejemplos:

• =DATESTR({Date Picker}) devolverá el valor de la columna Date Picker en formato YYYY-MM-DD, como 2030-06-19.
• =DATESTR(TODAY()) devolverá #VALUE!.
• =DATESTR(NOW()) devolverá #VALUE!.

DATETIME_DIFF

Devuelve la diferencia entre dos fechas en unidades específicas (por defecto: horas).

Sintaxis:

DATETIME_DIFF(date1,date2[,unit])

Las unidades aceptadas son:

• years
• months
• days
• hours

Ejemplos:

• =DATETIME_DIFF({Date of Birth},TODAY(),"years") devolverá la edad o el número de años entre Date of Birth (Selector de Fecha) y hoy.
• =DATETIME_DIFF("01/20/1900","01/22/1900","days") devolverá 2.
• =DATETIME_DIFF("01/22/1900","01/20/1900","hours") devolverá -48.

DATETIME_FORMAT

Cambia la forma en que aparece un datetime aplicando format. El parámetro datetime acepta únicamente valores de tipo de columna Selector de Fecha o Fecha y Hora. Para otros tipos de valores y formatos de retorno, consulta TEXT.

Sintaxis:

DATETIME_FORMAT(datetime,format)

Ejemplos:

• =DATETIME_FORMAT({Date Picker},"YYYY-MM-DD HH:mm:ss") devolverá el valor de la columna Date Picker en formato “YYYY-MM-DD HH:mm:ss”, como 1900-01-20 18:30:00.
• =DATETIME_FORMAT({Date Picker},"MMMM D, YYYY hh:mm a") devolverá el valor de la columna Date Picker en formato “MMMM D, YYYY hh:mm a”, como November 9, 1999 11:20 pm.

Aquí tienes una lista de especificadores de formato de fecha y hora aceptados:

Formato	Descripción	Ejemplos
YY	El año, del 00 al 99.	03, 17
YYYY	El año como un número de cuatro dígitos.	2003, 2017
M	El mes, del 1 al 12.	6, 12
MM	El mes como un número de dos dígitos.	06, 12
MMM	El nombre abreviado del mes.	Jun, Dec
MMMM	El nombre completo del mes.	June, December
D	El día del mes, del 1 al 31.	1, 15
DD	El día del mes, del 01 al 31.	01, 15
d	El día de la semana, del 0 al 6, siendo 0 el domingo.	0, 5
dd	El nombre corto del día de la semana.	Su, Fr
ddd	El nombre abreviado del día de la semana.	Sun, Fri
dddd	El nombre completo del día de la semana.	Sunday, Friday
H	La hora, usando un reloj de 24 horas del 0 al 23.	1, 23
HH	La hora, usando un reloj de 24 horas del 00 al 23.	01, 23
h	La hora, usando un reloj de 12 horas del 1 al 12.	1, 11
hh	La hora, usando un reloj de 12 horas del 01 al 12.	01, 11
m	El minuto, del 0 al 59.	5, 50
mm	El minuto, del 00 al 59.	05, 50
s	El segundo, del 0 al 59.	3, 30
ss	El segundo, del 00 al 59.	03, 30
A	Antes o después del mediodía en mayúsculas.	AM, PM
a	Antes o después del mediodía en minúsculas.	am, pm

DAY

Devuelve el día del mes de la fecha, que va del 1 al 31.

Sintaxis:

DAY(date)

Ejemplos:

• =DAY("1900-01-20") devolverá 20.
• =DAY("June 19, 2024") devolverá 19.
• =DAY({Date Picker}) devolverá el día del mes del valor de Date Picker, como 28.
• =DAY(TODAY()) devolverá el día del mes de la fecha actual.

FROMNOW

Cuenta el número de días desde ahora hasta un datetime determinado. El parámetro datetime acepta únicamente valores de tipo de columna Selector de Fecha o Fecha y Hora.

Sintaxis:

FROMNOW(datetime)

Ejemplos:

• =FROMNOW({Date Picker}) devolverá el número de días desde ahora hasta Date Picker.
• =FROMNOW({Reservation Date}) devolverá un número positivo si Reservation Date está en el futuro.

HOUR

Devuelve el valor de la hora del tiempo, que va del 0 (medianoche) al 23 (11:00 PM). La función HOUR también funciona con números o números de serie de datetime.

Sintaxis:

HOUR(time|number)

Ejemplos:

• =HOUR("12 am") devolverá 0.
• =HOUR("11:15 PM") devolverá 23.
• =HOUR("16:20") devolverá 16.
• =HOUR("18:42:59") devolverá 18.
• =HOUR(TIMESTR({Date Picker}) devolverá el valor de la hora del tiempo de Date Picker, como 23.
• =HOUR(NOW()) devolverá la hora del tiempo actual.
• =HOUR(0.5) devolverá 12.
• =HOUR(2.75) devolverá 18.

IS_AFTER

Devuelve TRUE si datetime1 está después de datetime2 y FALSE en caso contrario. Los parámetros datetime aceptan únicamente valores de tipo de columna Selector de Fecha o Fecha y Hora.

Sintaxis:

IS_AFTER(datetime1,datetime2)

Ejemplos:

• =IS_AFTER({Reservation Date},{Current Date}) devolverá TRUE o 1 si Reservation Date está en el futuro o es posterior a Current Date.
• =IS_AFTER({Date Picker},TODAY()) devolverá #VALUE!.
• =IS_AFTER({Date Picker},NOW()) devolverá #VALUE!.

IS_BEFORE

Devuelve TRUE si datetime1 está antes de datetime2 y FALSE en caso contrario. Los parámetros datetime aceptan únicamente valores de tipo de columna Selector de Fecha o Fecha y Hora.

Sintaxis:

IS_BEFORE(datetime1,datetime2)

Ejemplos:

• IS_BEFORE({Date of Birth},{Current Date}) devolverá TRUE o 1 si Date of Birth está en el pasado o es anterior a Current Date.
• =IS_BEFORE({Date Picker},TODAY()) devolverá #VALUE!.
• =IS_BEFORE({Date Picker},NOW()) devolverá #VALUE!.

IS_SAME

Compara dos fechas hasta una unidad y devuelve TRUE si son idénticas y FALSE en caso contrario. Los parámetros datetime aceptan únicamente valores de tipo de columna Selector de Fecha o Fecha y Hora.

Sintaxis:

IS_SAME(datetime1,datetime2,unit)

Las unidades aceptadas son:

• years
• months
• days
• hours
• minutes

Ejemplos:

• =IS_SAME({Appointment},{Current Date},"days") devolverá TRUE o 1 si Appointment es el mismo día que Current Date.
• =IS_SAME({Date Picker},TODAY(),"days") devolverá #VALUE!.
• =IS_SAME({Date Picker},NOW(),"days") devolverá #VALUE!.

MINUTE

Devuelve el valor de los minutos del tiempo, que va del 0 al 59.

Sintaxis:

MINUTE(time|number)

Ejemplos:

• =MINUTE(NOW()) devolverá el valor de los minutos del tiempo actual, como 23.
• =MINUTE("11:15 PM") devolverá 15.
• =MINUTE("18:42:59") devolverá 42.
• =MINUTE(0.02084) devolverá 30.
• =MINUTE({Date Picker}) devolverá el valor de los minutos del tiempo de Date Picker, como 59.

MONTH

Devuelve el mes de la fecha, que va del 1 (enero) al 12 (diciembre).

Sintaxis:

MONTH(date)

Ejemplos:

• =MONTH("January 1, 1900") devolverá 1.
• =MONTH("2030-12-25") devolverá 12.
• =MONTH(TODAY()) devolverá el nº mes de la fecha actual, como 7.

NOW

Devuelve el número de serie de la fecha y hora actual o el número de días desde el 1 de enero de 1900. La función NOW no tiene argumentos.

Sintaxis:

NOW()

Ejemplos:

• =NOW() devolverá el número de serie de la fecha y hora actual, como 44769.670104167.
• =TEXT(NOW(),"YYYY-MM-DD HH:MM:SS") devolverá la fecha y hora actual en formato “YYYY-MM-DD HH:MM:SS”, como 2022-07-28 10:19:31.
• =HOUR(NOW()) devolverá la hora del tiempo actual.

SECOND

Devuelve el valor de los segundos del tiempo, que va del 0 al 59.

Sintaxis:

SECONDS(time|number)

Ejemplos:

• =SECOND("15:30:45") devolverá 45.
• =SECOND(0.000175) devolverá 15.
• =SECONDS(NOW()) devolverá el valor de los segundos del tiempo actual, como 59.

TIMESTR

Devuelve el tiempo del valor datetime en formato HH:MM:SS. El parámetro datetime acepta únicamente valores de tipo de columna Selector de Fecha o Fecha y Hora. Para otros tipos de valores y formatos de retorno, consulta TEXT.

Sintaxis:

TIMESTR(datetime)

Ejemplos:

• =TIMESTR({Date Picker}) devolverá el tiempo del valor de Date Picker, como 23:30:00.
• =TIMESTR(TODAY()) devolverá #VALUE!.
• =TIMESTR(NOW()) devolverá #VALUE!.

TODAY

Devuelve la fecha actual en formato M/DD/YYYY. La función TODAY no tiene argumentos.

Sintaxis:

TODAY()

Ejemplos:

• =TODAY() devolverá la fecha actual, como 7/27/2022.
• =DAY(TODAY()) devolverá el día del mes de la fecha actual, como 27.

TONOW

Cuenta el número de días desde un datetime determinado hasta ahora. El parámetro datetime acepta únicamente valores de tipo de columna Selector de Fecha o Fecha y Hora.

Sintaxis:

TONOW(datetime)

Ejemplos:

• =TONOW({Date Picker}) devolverá el número de días desde Date Picker hasta ahora.
• =TONOW({Date of Birth}) devolverá un número positivo si Date of Birth está en el pasado.

WEEKDAY

Devuelve el día de la semana de la fecha, que va del 1 (domingo) al 7 (sábado).

Sintaxis:

WEEKDAY(date[,type])

El parámetro opcional type determina el tipo de valor de retorno:

Tipo	Número Devuelto
1 u omitido	Números del 1 (domingo) al 7 (sábado).
2	Números del 1 (lunes) al 7 (domingo).
3	Números del 0 (lunes) al 6 (domingo).

Ejemplos:

• =WEEKDAY("Sunday, July 3, 2022") devolverá 1.
• =WEEKDAY("Jul 4, 2022",2) devolverá 1.
• =WEEKDAY("2022-07-04",3) devolverá 0.
• =WEEKDAY({Date Picker}) devolverá el día de la semana del valor de Date Picker.
• =WEEKDAY(TODAY()) devolverá el día de la semana de la fecha actual.
• =WEEKDAY(NOW()) devolverá el día de la semana de la fecha actual.

WEEKNUM

Devuelve el número de semana de la fecha, que va de 1 hasta 53 semanas del año.

Sintaxis:

WEEKNUM(date)

Ejemplos:

• =WEEKNUM("Sunday, January 1, 2023") devolverá 1.
• =WEEKNUM("Feb 1, 2023") devolverá 5.
• =WEEKNUM("2023-12-31") devolverá 53.
• =WEEKNUM({Date Picker}) devolverá el número de semana del valor de Date Picker.
• =WEEKNUM(TODAY()) devolverá el número de semana de la fecha actual.
• =WEEKNUM(NOW()) devolverá #VALUE!.

WORKDAY

Devuelve el número de serie de la fecha antes o después de una fecha de inicio, especificado por el número de días laborables y una lista opcional de días festivos en formato YYYY-MM-DD.

Sintaxis:

WORKDAY(date,days[,holiday1,holiday2,...])

Ejemplos:

• =WORKDAY("Monday, January 1, 2024",1) devolverá 45293 que es equivalente al martes, 2 de enero de 2024.
• =WORKDAY("Monday, January 1, 2024",1,"2024-01-02","2024-01-03") — un día laborable después del 1 de enero de 2024, excluyendo el 2 y 3 de enero del mismo año — devolverá 45295 que es equivalente al jueves, 4 de enero de 2024.
• =TEXT(WORKDAY({Date Picker},7),"YYYY-MM-DD") devolverá la fecha, 7 días laborables desde Date Picker, en formato YYYY-MM-DD, como 2022-07-24.

YEAR

Devuelve el año de la fecha, que va de 1900 a 9999.

Sintaxis:

YEAR(date)

Ejemplos:

• =YEAR("2025-01-21") devolverá 2025.
• =YEAR("June 4, 1997") devolverá 1997.
• =YEAR("{Date Picker}) devolverá el año del valor de Date Picker.
• =YEAR(TODAY()) devolverá el año de la fecha actual.
• =YEAR(NOW()) devolverá el año de la fecha actual.